VirtualBox

source: vbox/trunk/src/libs/dxvk-2.3.1/include/vulkan/CMakeLists.txt

最後變更 在這個檔案是 105107,由 vboxsync 提交於 9 月 前

libs/dxvk-2.3.1: Make it build, bugref:10716

  • 屬性 svn:eol-style 設為 native
  • 屬性 svn:keywords 設為 Author Date Id Revision
檔案大小: 3.1 KB
 
1# ~~~
2# Copyright 2018-2023 The Khronos Group Inc.
3# Copyright 2018-2023 Valve Corporation
4# Copyright 2018-2023 LunarG, Inc.
5#
6# SPDX-License-Identifier: Apache-2.0
7# ~~~
8cmake_minimum_required(VERSION 3.15...3.25)
9
10# NOTE: Parsing the version like this is suboptimal but neccessary due to our release process:
11# https://github.com/KhronosGroup/Vulkan-Headers/pull/346
12#
13# As shown a more robust approach would be just to add basic test code to check the project version.
14function(vlk_get_header_version)
15 set(vulkan_core_header_file "${CMAKE_CURRENT_SOURCE_DIR}/include/vulkan/vulkan_core.h")
16 if (NOT EXISTS ${vulkan_core_header_file})
17 message(FATAL_ERROR "Couldn't find vulkan_core.h!")
18 endif()
19
20 file(READ ${vulkan_core_header_file} ver)
21
22 if (ver MATCHES "#define[ ]+VK_HEADER_VERSION_COMPLETE[ ]+VK_MAKE_API_VERSION\\([ ]*[0-9]+,[ ]*([0-9]+),[ ]*([0-9]+),[ ]*VK_HEADER_VERSION[ ]*\\)")
23 set(MAJOR_VERSION "${CMAKE_MATCH_1}")
24 set(MINOR_VERSION "${CMAKE_MATCH_2}")
25 else()
26 message(FATAL_ERROR "Couldn't get major/minor version")
27 endif()
28
29 if (ver MATCHES "#define[ ]+VK_HEADER_VERSION[ ]+([0-9]+)")
30 set(PATCH_VERSION "${CMAKE_MATCH_1}")
31 else()
32 message(FATAL_ERROR "Couldn't get the patch version")
33 endif()
34
35 set(VK_VERSION_STRING "${MAJOR_VERSION}.${MINOR_VERSION}.${PATCH_VERSION}" PARENT_SCOPE)
36endfunction()
37vlk_get_header_version()
38
39project(VULKAN_HEADERS LANGUAGES C VERSION ${VK_VERSION_STRING})
40
41add_library(Vulkan-Headers INTERFACE)
42add_library(Vulkan::Headers ALIAS Vulkan-Headers)
43target_include_directories(Vulkan-Headers INTERFACE $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>)
44
45if (CMAKE_VERSION VERSION_LESS "3.21")
46 # https://cmake.org/cmake/help/latest/variable/PROJECT_IS_TOP_LEVEL.html
47 string(COMPARE EQUAL ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_SOURCE_DIR} PROJECT_IS_TOP_LEVEL)
48endif()
49
50if (PROJECT_IS_TOP_LEVEL)
51 option(BUILD_TESTS "Build the tests")
52 if (BUILD_TESTS)
53 enable_testing()
54 add_subdirectory(tests)
55 endif()
56
57 include(GNUInstallDirs)
58 include(CMakePackageConfigHelpers)
59
60 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/include/vk_video" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
61 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/include/vulkan" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
62 # Preserve source permissions https://github.com/KhronosGroup/Vulkan-Headers/issues/336
63 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/registry" DESTINATION "${CMAKE_INSTALL_DATADIR}/vulkan" USE_SOURCE_PERMISSIONS)
64
65 set_target_properties(Vulkan-Headers PROPERTIES EXPORT_NAME "Headers")
66
67 install(TARGETS Vulkan-Headers EXPORT VulkanHeadersConfig INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
68 install(EXPORT VulkanHeadersConfig NAMESPACE "Vulkan::" DESTINATION "share/cmake/VulkanHeaders")
69
70 set(version_config "${CMAKE_CURRENT_BINARY_DIR}/generated/VulkanHeadersConfigVersion.cmake")
71 write_basic_package_version_file("${version_config}" COMPATIBILITY SameMajorVersion ARCH_INDEPENDENT)
72 install(FILES "${version_config}" DESTINATION "share/cmake/VulkanHeaders")
73endif()
注意: 瀏覽 TracBrowser 來幫助您使用儲存庫瀏覽器

© 2025 Oracle Support Privacy / Do Not Sell My Info Terms of Use Trademark Policy Automated Access Etiquette